Шпаргалка по Power Query (язык M)

**Помни: M – это чувствительный к регистру язык!** "**А**" **и** "**а**" **– не одно и то же.**

|  |  |  |
| --- | --- | --- |
| **Тип данных** | **Коротко** | **Подробно** |
| null | null | Пустое значение. Это не ноль и не пустая строка.  1 \* null = null // будь внимателен! |
| logical | true / false | Истина / ложь |
| number | 0 1 -1 1.5 2.3e-5, 0xff (hex) | Целое / действительное число |
| time | #time(9, 15, 0) – время  Если час = 24, то минуты и секунды должны быть = 0 | #time( часы, минуты, секунды )  #time(24,0,0) = #time(0,0,0)  0 ≤ часы ≤ 24, 0 ≤ минуты ≤ 59, 0 ≤ секунды ≤ 59 |
| date | #date(2013, 2, 26) | #date( год, месяц, день ) – дата |
| datetime | #datetime(2013, 2, 26, 9, 15, 0) | #datetime( год, месяц, день, часы, минуты, секунды) |
| datetimezone | #datetimezone(2013, 2, 26, 9, 15, 0, 9, 0) | #datetimezone( год, месяц, день, часы, минуты, секунды, сдвиг часов, сдвиг минут), Дата-время с часовым поясом. Диапазоны значений:  0 ≤ год ≤ 9999, 0 ≤ месяц ≤ 12, 1 ≤ день ≤ 31  0 ≤ часы ≤ 23, 0 ≤ минуты ≤ 59, 0 ≤ секунды ≤ 59  -14 ≤ сдвиг часов + сдвиг минут / 60 ≤ 14 |
| duration | #duration( 0, 1, 30, 0) | #duration(дни, часы, минуты, секунды) -Длительность |
| text | "hello"  Строка с переносом ="a#(cr,lf)b"  = "a" & "b""c" // ab"c – включение кавычки в строку | Текст - это просто строка в кавычках  Специальные символы: перенос строки  ="#(cr,lf)" тоже что и ="#(cr)#(lf)",  = "a#(tab)b" // a b - табуляция |
| binary | #binary("AQID") | Кто работает с binary, тот знает |
| list | { 1, 2, 3 }, { 1 .. 10 },  {"A".."Z", "a".."z"} | list (список) это набор значений, разделенных запятой, заключенный в фигурные скобки |
| record | [ A=1, B=2 ]  Запись может хранить несколько полей. Тип значения в записи может быть любым. | Запись: "Имя поля = значение" в квадратных скобках. |
| table | Простая таблица (без указания типа данных):  #table( { "X", "Y" }, { { 1, 2 }, { 3, 4 } } )  Желательно указывать тип данных  #table( type table  [Digit ID = number, Name = text],  { {1,"one"},  {2,"two"},  {3,"three"} } )  Таблица без строк:  #table( {"A", "B"}, {} ) | Что получится:  C:\Users\bondaiva\AppData\Local\Temp\msohtmlclip1\02\clip_image001.png  #table( список названий столбцов (полей),  Список из списков значений для строк будущей таблицы)  #table( { "Столбец 1", "Столбец 2" },  { { "Столбец1 Значение1", "Столбец2 Значение1" },   { "Столбец1 Значение2", " Столбец2 Значение2" },  { " Столбец1 Значение3", " Столбец2 Значение2" } } ) |
| function | (x) => x + 1  Функция более сложная (x as number) =>  let  a=x+1,  b=a\*2  in  b | ( аргументы ) => тело функции.  (optional num as nullable number) =>  let  step1 = if num = null then 0 else num,  step2 = step1 \* 2  in  step2 |
| type | type{ number } // list  type table [A = any, B = text] | Тип данных «Тип», позволяет получить / проверит / задать Тип каким-то данным |

|  |  |  |  |
| --- | --- | --- | --- |
| Оператор |  | x = y | Равно |
| x > y | Больше | x<>y | Не равно |
| x >= y | Больше либо равно | x or y | Условие ИЛИ |
| x < y | Меньше | x and y | Условие И |
| x <= y | Меньше либо равно | not x | Логическое отрицание НЕ |

|  |  |
| --- | --- |
| **Выражение**  "Кто виноват?" // текст, т.к. в кавычках  123 // число, т.к. без кавычек  1 + 2 // сумма чисел  {1, 2, "3"} // список из трех элементов, "3" - текст  [ x = 1, y = 2 + 3 ] // запись с двумя полями  (x, y) => x + y // функция, выполняющая сложение  if 2 > 1 then 2 else 1 // выражение проверяющее условие «если / то / иначе»  **let** x = 1 + 1 **in** x \* 2 // пример выражения **let**  error "A" // ошибка с сообщением "A" | **Рекурсия (**[blog post](http://www.thebiccountant.com/2017/09/26/recursion-m-beginners/)**)**  Factorial = (n) =>  if n <= 1 then  1  else  n \* **@**Factorial(n - 1),  x = Factorial(5)  // **@** - оператор вызова исходной функции  **let –** ключевое слово, начинающее «раздел» вычислений – несколько операций. Конец этого раздела обязательно должен быть обозначен ключевым словом **in**. После **in** тоже может быть какое-то действие. Но чаще - просто ссылка на шаг перед **in**. |

**Относительные диапазоны дат**

Сегодня= Date.From(DateTime.FixedLocalNow()),

Вчера= Date.AddDays(Date.From(DateTime.FixedLocalNow()), -1),

#"Конец предыдущего месяца" = Date.EndOfMonth(Date.AddMonths(DateTime.FixedLocalNow(), -1)),

#"Начало текущего года"= Date.StartOfYear( DateTime.FixedLocalNow() ),

#"Начало предыдущего года"= Date.AddYears(Date.StartOfYear(DateTime.FixedLocalNow()), -1),

#"Дата в формате ISO"=Date.ToText( Date.From(DateTime.FixedLocalNow()), "yyyy-MM-ddT00:00:00"),

#"Начало месяца 12 месяцев назад исключая текущий"= Date.StartOfMonth(Date.AddMonths(DateTime.FixedLocalNow(), -12)),

#" Начало месяца 12 месяцев назад включая текущий "= Date.StartOfMonth(Date.AddMonths(DateTime.FixedLocalNow(), -11)),

// Генерация календаря – ([blog post](https://bondarenkoivan.wordpress.com/2015/10/10/generation-of-custom-calendars-in-power-query/)), [solution for Power BI](https://github.com/migueesc123/CalendarCreator4PowerBI)

// Список дат в диапазоне Предыдущий год-> Сегодня

let

start = Date.AddYears(Date.StartOfYear(DateTime.FixedLocalNow()), -1), // start of prev year

end = Date.From(DateTime.FixedLocalNow()), // today

duration = Duration.Days(end - start) + 1,

list\_of\_dates = List.Dates(start, duration, #duration(1,0,0,0)),

#"Table from List" = Table.FromList(list\_of\_dates, Splitter.SplitByNothing(), null, null, ExtraValues.Error)

in

#"Table from List"

Где взять рабочие дни – смотри [solution from Marco Russo](https://github.com/marcosqlbi/DaxDateTemplate)

Опция 1: [Parse table from TimeAndDate.com](https://www.timeanddate.com/calendar/custom.html?ctf=4&hol=9&typ=3&hod=7&holmark=1&display=2&cdt=1&wdf=4&mtm=2&cols=1&country=20&year=2017&y2=2018)

Опция 2: [Use API TimeAndDate.com](https://datachant.com/2017/04/13/calendar-with-working-days-power-bi/)

Для России: [читать в блоге](https://bondarenkoivan.wordpress.com/2016/11/23/%D1%81%D0%BA%D0%B0%D1%87%D0%B0%D1%82%D1%8C-%D0%BF%D1%80%D0%BE%D0%B8%D0%B7%D0%B2%D0%BE%D0%B4%D1%81%D1%82%D0%B2%D0%B5%D0%BD%D0%BD%D1%8B%D0%B9-%D0%BA%D0%B0%D0%BB%D0%B5%D0%BD%D0%B4%D0%B0%D1%80%D1%8C/), [function on GitHub](https://github.com/IvanBond/pquery/blob/master/List.Dates.HolidaysRU.pq)

Заготовки для Power Query

**Если / То/ Иначе**

Result = if [Column1]>0 then [Column A] else [Column B] // строчными if / then / else

**TRY / CATCH – аналог функции ЕСЛИОШИБКА в Excel**

Result = try A/B otherwise 0 // строчными “**try** [опасная операция] **otherwise** [в случае ошибки]”

**Значение из ячейки Excel (Именованный диапазон из одной ячейки)**

Result = Excel.CurrentWorkbook(){[Name="ИМЯДИАПАЗОНА"]}[Content]{0}[Column1]

**Переименование столбцов с помощью заранее заготовленной таблицы** RENAMING\_TABLE

Renamed\_Columns = Table.RenameColumns(ЦЕЛЕВАЯТАБЛИЦА, Table.ToColumns(Table.Transpose(RENAMING\_TABLE)), MissingField.Ignore),

где таблица RENAMING\_TABLE выглядит так (заголовки могут быть любыми)

|  |  |
| --- | --- |
| Старое имя | Новое имя |
| Нск | Новосибирск |
| Питер | Санкт-Петербург |

**Используя функцию List.Zip, когда известен порядок столбцов (**[blog post](https://datachant.com/2017/01/26/power-bi-pitfall-6/)**)**

Renamed\_Columns = Table.RenameColumns(TARGET,

List.Zip( { Table.ColumnNames( Source ), { "Организация", "Магазин" } } ) , MissingField.Ignore),

**Создание таблицы «из воздуха»**

Например, результат запроса в веб-сервис вернул null, но в Модель Данных надо грузить нормальную таблицу, иначе всё сломается

= #table( {"A", "B"}, {} ) – пустая таблица, простой подход. Опасен тем, что не заданы типы данных!

Лучше задать тот тип данных, который Модель Данных (Power Pivot) ожидает

= #table( type table [Мой Столбец = text, Твой Столбец = number], {} ) – пустая, но типы данных заданы

= #table( type table [Столб A = text, B = number], { {"раз", 1}, {"два", 1} } ) – таблица с парой строк

**ISNUMBER() аналог**

= "пример" is number // ложь; = 123 is number // истина

**ISTEXT() аналог**

= "пример" is text // истина; = 123 is text // ложь

**Привести все столбцы таблицы к текстовому типу данных**

= Table.TransformColumnTypes(Source,

List.Transform( Table.ColumnNames(Source), each { \_, type text } ) )

**Развернуть из вложенной таблицы столбцы, имен которых нет в текущей таблице**

= Table.ExpandTableColumn( buffer, "NewColumn",

List.Difference( Table.ColumnNames( buffer[NewColumn]{0} ), Table.ColumnNames( buffer ) ),

List.Difference( Table.ColumnNames( buffer[NewColumn]{0} ), Table.ColumnNames( buffer ) ) )

**Развернуть из вложенной таблицы только столбцы из специального списка**

  // в качестве списка берем столбец Attribute из таблицы INPUT\_TABLE

fields = List.Buffer( InputTable[Attribute] ),

#"Expanded NewColumn" = Table.ExpandTableColumn( buffer, "NewColumn",

List.Intersect( { List.Difference( Table.ColumnNames( buffer[NewColumn]{0} ), Table.ColumnNames( buffer ) ), fields } ) ,

List.Intersect( { List.Difference( Table.ColumnNames( buffer[NewColumn]{0} ), Table.ColumnNames( buffer ) ), fields } ) ),

**Развернуть столбцы из спец списка и переименовать их в процессе**

fields = List.Buffer( InputTable[Attribute] ),

#"Expanded NewColumn" = Table.ExpandTableColumn( buffer, "NewColumn",

List.Intersect( { Table.ColumnNames( buffer[NewColumn]{0} ), fields } ),

// добавляем приставку Parent к имени каждого разворачиваемого столбца

List.Transform( // переименование по таблице RENAME\_TABLE путём подмены элементов списка

[List.ReplaceMatchingItems](https://msdn.microsoft.com/en-us/library/mt253640.aspx)( List.Intersect( { Table.ColumnNames( buffer[NewColumn]{0} ),

fields } ),

Table.ToColumns( Table.Transpose(RENAME\_TABLE)) ),

each "Parent " & \_ )

),

**Работа с запросами в SQL сервер (**[blog post](https://bondarenkoivan.wordpress.com/2016/07/17/query-folding-and-dynamic-parameters/)**)**

// Старайтесь фильтровать в Power Query сразу же после операции Sql.Database, тогда фильтрация будет происходить на стороне сервера.

// чтобы сформировался запрос с условием “IN” используйте функцию List.Contains

Table.SelectRows( Source, each [OrganizationKey]=11 and

List.Contains( {6,7}, [DepartmentGroupKey] ) )

// будет преобразовано в WHERE OrganizationKey = 11 and DepartmentGroupKey in (6, 7)

**Библиотеки с дополнительными функциями для Power Query**

<https://github.com/Hugoberry/PowerQueryExtensions> + [Hugoberry’s Gist](https://gist.github.com/Hugoberry)

<https://github.com/tycho01/pquery>

<https://github.com/tnclark8012/Power-BI-Desktop-Query-Extensions>

<https://github.com/ImkeF/RM>

<https://github.com/hohlick/PowerQueryModules>

<https://github.com/acaprojects/m-tools>

Операции с датой и временем в Power Query

**Время**

**#time( часы, минуты, секунды )**

|  |  |  |  |
| --- | --- | --- | --- |
| **Оператор** | **Слева** | **Справа** | **Результат** |
| x + y | time | duration | Сдвиг времени |
| x + y | duration | time | Сдвиг времени |
| x - y | time | duration | Сдвиг времени |
| x - y | time | time | Длительность между Т1 и Т2 |
| x & y | date | time | Дата + Время |

**Дата**

**#date( год, месяц, день )**

|  |  |  |  |
| --- | --- | --- | --- |
| **Оператор** | **Слева** | **Справа** | **Результат** |
| x + y | date | duration | Сдвиг даты / времени |
| x + y | duration | date | Сдвиг даты / времени |
| x - y | date | duration | Сдвиг даты / времени (назад) |
| x - y | date | date | Длительность между датами |
| x & y | date | time | Дата + Время |

**ДатаВремя**

**#datetime( год, месяц, день, часы, минуты, секунды )**

|  |  |  |  |
| --- | --- | --- | --- |
| **Оператор** | **Слева** | **Справа** | **Результат** |
| x + y | datetime | duration | Сдвиг даты / времени |
| x + y | duration | datetime | Сдвиг даты / времени |
| x - y | datetime | duration | Сдвиг даты / времени (назад) |
| x - y | datetime | datetime | Длительность между двумя моментами времени |

**Длительность**

**#duration( дни, часы, минуты, секунды)**

#duration(0, 0, 0, 5.5) // 5.5 секунд

#duration(0, 0, 0, -5.5) // -5.5 секунд

#duration(0, 0, 5, 30) // 5.5 минут

#duration(0, 0, 5, -30) // 4.5 минут

#duration(0, 24, 0, 0) // 1 день

#duration(1, 0, 0, 0) // 1 день

|  |  |  |  |
| --- | --- | --- | --- |
| **Оператор** | **Слева** | **Справа** | **Результат** |
| x + y | datetime | duration | Сдвиг даты / времени |
| x + y | duration | datetime | Сдвиг даты / времени |
| x + y | duration | duration | Новая длительность |
| x - y | datetime | duration | Сдвиг даты / времени (назад) |
| x - y | datetime | datetime | Длительность между датами |
| x - y | duration | duration | Разница в длительности |
| x \* y | duration | number | N раз длительность |
| x \* y | number | duration | N раз длительность |
| x / y | duration | number | Доля длительности |

Основной источник –спецификация к языку M: <https://msdn.microsoft.com/en-us/library/mt211003.aspx>

Актуальная версия шпаргалки: <https://github.com/IvanBond/Power-Query-Cheat-Sheet>

Рекомендуемые блоги

<https://bondarenkoivan.wordpress.com/> - [Ivan Bondarenko](https://www.linkedin.com/in/bondarenkoivan/) ([@\_Ivan\_Bond](https://twitter.com/_ivan_bond))

<https://blog.crossjoin.co.uk/> - [Chris Webb](https://www.linkedin.com/in/chriswebb6/) ([@Technitrain](https://twitter.com/Technitrain))

<http://datachant.com/> - [Gil Raviv](https://www.linkedin.com/in/gilraviv/) ([@gilra](https://twitter.com/gilra))

<https://www.excelguru.ca/blog> - [Ken Puls](https://www.linkedin.com/in/kenpuls/) ([@kpuls](https://twitter.com/kpuls))

<https://querypower.com/> - [Igor Cotruta](https://www.linkedin.com/in/igorco/) ([@igocrete](https://twitter.com/igocrete))

<http://exceleratorbi.com.au/> - [Matt Allington](https://www.linkedin.com/in/mattallington/) ([@ExceleratorBI](https://twitter.com/ExceleratorBI))

<http://excel-inside.pro/> - [Maxim Zelensky](https://www.linkedin.com/in/maximzelensky/) ([@Hohlick](https://twitter.com/Hohlick))

<http://www.thebiccountant.com/> - [Imke Feldman](https://www.linkedin.com/in/imkefeldmann/) ([@TheBiccountant](https://twitter.com/TheBIccountant))

<https://powerpivotpro.com/> - [Rob Collie](https://www.linkedin.com/in/robcollie/), [Avi Singh](https://www.linkedin.com/in/avichalsingh/) and others ([@powerpivotpro](https://twitter.com/powerpivotpro))

На русском:

<https://www.facebook.com/groups/Excelforever/>

<http://www.excel-vba.ru/?s=power+query>

<http://needfordata.ru/blog/>

<https://bondarenkoivan.wordpress.com/> - [Ivan Bondarenko](https://www.linkedin.com/in/bondarenkoivan/) ([@\_Ivan\_Bond](https://twitter.com/_ivan_bond))

Автор – Иван Бондаренко



<https://bondarenkoivan.wordpress.com/>

Twitter: [@\_Ivan\_Bond](https://twitter.com/_Ivan_Bond)

[Ivan Bondarenko](https://bondarenkoivan.wordpress.com/about/) - 19-Oct-2017